Flash｜基礎｜応用｜

sample一覧↓

alpha値の往復

参照

上部Flash-alpha：A、B、C、D

共通の値

形状
矩形：w85×h85
変化値
10
1フレームごとに10 （％）づつ値を変化する。
※この値が大きいほど1フレームごとの変化が大きい＝変化の速度が速くなる。
最大最小値
20〜100
20（％）から100（％）の範囲で、透明度を10％づつ増加（または減少）して、
最大最小値を往復する。
actionscript記述場所
各ムービークリップに記述

各MCのactionscript

onClipEvent (load) {
this._alpha=100;//なくてもよい
speed = 10;
}
onClipEvent (enterFrame) {
this._alpha += speed;
if (this._alpha>100 || this._alpha<20) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//初期値の設定・・・必須
speed = 10;
}
onClipEvent (enterFrame) {
this._alpha=mcA;//左右逆転不可
mcA += speed;
if (mcA>100 || mcA<20) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//必須
speed = -10;
}
onClipEvent (enterFrame) {
this._alpha=mcA;//左右逆転不可
mcA += speed;
if (mcA<20) {
speed = 10;
} else if (mcA>100) {
speed = -10;
}
}

onClipEvent (load) {
mcA = 100;//必須
flg = 1;
speed = 10;
}
onClipEvent (enterFrame) {
this._alpha = mcA;//左右逆転不可
mcA += flg*speed;
if (mcA<20) {
flg = 1;
}
if (mcA>100) {
flg = -1;
}
}

Aの記述が一番短く、直感的にわかりやすいが、原因不明のエラー（？）が起こる場合がある。具体的な現象は、往復の数回目に突如、一定の値でとまっているような微細なループ点滅を起こすというもの。比較演算子に=を足したり、ムービークリップを単独使用にしたり、初期値を追加削除しても、エラーが起こる場合と起こらない場合の条件がいまいち不明。ステージ上にalpha値を変化する他のムービークリップがあると、エラーが起こりやすいのかもしれないが、何も問題が起こらないこともある。
Bのように、this._alpha=mcAとひとつ代入式を追加すると、その問題は一回も起こらない。Aが他の式に比べ、往復回数が微妙に速いのもエラーが起こるのと同じ原因なのかも。不安定なので、alpha値の往復運動にはBを使用するのが妥当。
BとDは同じ内容の式。指定した範囲をこえたら変化値の正負を逆転するやり方。（最大値100をこえたら10を-10に、最小値20をこえたら-(-10)に。）往復回数がAやCに比べ、揃っているのも同じ正負を逆転するやり方だからかも。
Dのflg*speed、flg = 1;、flg = -1;と条件式をひとつにまとめたものがB。
D は参考書などによく載っている例。もっと複雑な動きをする場合に応用が利きそう。
C は条件によって、speedの値を直接代入する式。一番確実な方法にみえるが、変化値を変更する際に少々面倒。減少のときと増加のときの速度が異なる場合などは重宝するかも。

scale値の往復

参照

上部Flash-scale：A、B、C、D、a、b、c、d
応用　shirokuma Link naviの風見鳥→

共通の値

形状
矩形（増減用）：w200×h20（A、B、C、D）
魚（反転用）：w200（a、b、c、d）
変化値
10
1フレームごとに10（％）づつ値を変化する。
※この値が大きいほど1フレームごとの変化が大きい＝変化の速度が速くなる。
最大最小値
矩形（増減用）：xscale｜20〜100
20（％）から100（％）の範囲で、横幅を10％づつ増加（または減少）して、
最大最小値を往復する。

魚（反転用）：xscale｜-100〜100
※xscale値にマイナスの値を代入すると形状が左右反転する。
（yscaleのときは上下反転）
0（％）から100（％）の範囲で、横幅を10％づつ増加（または減少）して、
0（％）から-100（％）の範囲で、反転した魚の横幅を、10％づつ増加（または減少）する。三次元回転のようにy軸を中心に右向き左向きを反転し続ける。
actionscript記述場所
各ムービークリップに記述

各MCのactionscript：増減

onClipEvent (load) {
this._xscale=100;//なくてもよい
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale += speed;
if (this._xscale>100 || this._xscale<20) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//必須
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale=mcA;//左右逆転不可
mcA += speed;
if (mcA>100 || mcA<20) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//必須
speed = -10;
}
onClipEvent (enterFrame) {
this._xscale=mcA;//左右逆転不可
mcA += speed;
if (mcA<20) {
speed = 10;
} else if (mcA>100) {
speed = -10;
}
}

onClipEvent (load) {
mcA = 100;//必須
flg = 1;
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale = mcA;//左右逆転不可
mcA += flg*speed;
if (mcA<20) {
flg = 1;
}
if (mcA>100) {
flg = -1;
}
}

基本的に式は_alphaと同じ。ただ、alpha値で起こっていたAのエラーが、確認する限り起こらない。
alphaの場合と同じように、BやDに比べ速度が微妙にはやいので根本的な要因は残っているのかも。
Aの初期値は入れても入れなくても同じ結果になるが、以下の反転の場合は初期値が必須になる。

各MCのactionscript：反転

onClipEvent (load) {
this._xscale=100;//必須
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale += speed;
if (this._xscale>100 || this._xscale<-100) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//必須
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale=mcA;//左右逆転不可
mcA += speed;
if (mcA>100 || mcA<-100) {
speed = -speed;
}
}

onClipEvent (load) {
mcA=100;//必須
speed = -10;
}
onClipEvent (enterFrame) {
this._xscale=mcA;//左右逆転不可
mcA += speed;
if (mcA<-100) {
speed = 10;
} else if (mcA>100) {
speed = -10;
}
}

onClipEvent (load) {
mcA = 100;//必須
flg = 1;
speed = 10;
}
onClipEvent (enterFrame) {
this._xscale = mcA;//左右逆転不可
mcA += flg*speed;
if (mcA<-100) {
flg = 1;
}
if (mcA>100) {
flg = -1;
}
}

上記にも記したとおり、Aの場合でも初期値が必須になる。その他にも、AとBの場合は初期値と最大値が同じ値でないとエラーが起こる。この場合は、初期値（100）、最大値（>100）。値を一致すれば100（％）でなくてもよい。
ただ、オブジェクトの形状がshirokuma Link naviの風見鳥のように線が細い場合、最大値を100にすると実際のxscaleより横に膨張してみえる。99にすると、実際より伸縮してみえる。
CとDは初期値と最大値が一致しなくても使えるので、風見鳥の設定はDを使用して、初期値を100、最大最小値をそれぞれ99、-99にしてちょうど良い形状を保っている。

マウスポインタを追随するMCの関数の設定、および三角関数での角度の制限

参照

上部Flash-rotation-special：E、1、2
応用：shirokuma Link naviのTVアンテナ→

共通の値、設定

制作の注意点
オブジェクトは水平右方向がマウスを追随する先端になるように作成。「→」
シンボルに変換するときは、基準点は左辺中央に設定。「+→」
※ラジアンの基準は水平右方向（x軸正）
actionscriptの注意点
※Mac OS上ではx,yの値がともに0のとき値0ではなく、NaNを返すことがある。
アクションが実行されないのを防ぐために、
設定する際は、if文でx,yの値がともに0のときのアクションを改めて指定する。
actionscript記述場所
各ムービークリップに記述。

onClipEvent (enterFrame) {
xM = _root._xmouse-this._x;
yM = _root._ymouse-this._y;
this._rotation = thisR;
if (xM == 0 && yM == 0 ) {
thisR = 0;
} else {
Radian = Math.atan2(yM, xM);
thisR = Radian*180/Math.PI;
}
}

onClipEvent (enterFrame) {
xM = _root._xmouse-this._x;
yM = _root._ymouse-this._y;
this._rotation = thisR;
if (xM == 0 && yM == 0) {
thisR = 0;
} else if (yM<0) {
Radian = Math.atan2(yM, xM);
thisR = Radian*180/Math.PI;
}
}

onClipEvent (enterFrame) {
xM = _root._xmouse-this._x;
yM = _root._ymouse-this._y;
this._rotation = thisR;
if (xM == 0 && yM == 0 ) {
thisR = 0;
} else {
if (yM<0) {
Radian = Math.atan2(yM, xM);
thisR = Radian*180/Math.PI;
} else if (yM>0) {
Radian = Math.atan2(yM, xM);
thisR = (Radian*180/Math.PI)*-1;
}
}
}

_root._xmouse、_root._ymouseでステージ上のマウスの座標を取得。ムービークリップの基準点を引いて、それぞれ高さと底辺を求めている。角度を求めている式はRadian = Math.atan2(yM, xM);の部分。値はラジアンで、水平方向の右（x軸正）を基準にしたマウスの方角をタンジェントの逆関数で計算している（Flashが）。thisR = (Radian*180/Math.PI)でラジアンを度数に変換し、this._rotation = thisR;でムービークリップのrotation値に度数を代入している。この関数がenterframeにより表示中ずっと読み込まれ続けるので、マウスを動かすたびにムービークリップのrotation値が変更される。
２は高さ（上図参照、式ではyM）の値が正か負かによってマウスを追随する角度を制限。Flashの基準は左上なので、ムービークリップの基準点より、マウスのy座標が上にあるとき、_root._ymouse-this._yの値は負になる。この場合だと値をyM<0で条件を負に制限し、上半分のみ反応するようにしている。yM>0だと下半分のみになる。横方向の場合は底辺（上図参照、式ではxM）の値が正か負かによって角度を制限できる。やはりFlashの基準は左上なので、マウスのx座標がムービークリップの基準点より左にあるとき_root._xmouse-this._xの値は負、xM<0で左側に制限。右にあるとき_root._xmouse-this._xの値は正、xM>0で右側に制限できる。
ステージのxy数値をそのまま使って_x、_yの移動範囲を制限すれば180度以下も簡単に設定できる。角度のある扇型範囲で制限するときはthisR = Radian*180/Math.PIの式の後に任意の角度をたす。（+60など。）ただ、２の方法だと、マウスが片側（例えば右から下）を抜け、条件を満たさなくなってムービークリップが停止し、反対側（左）で条件を満たしたときに、瞬間移動してくる。
Eは角度を上半分に制限しつつ、条件を満たさない下半分にマウスがあるときも、計算式の値に-1をかけて、角度を反転してマウスを追随し続けるようにした。